Orbit of critical point tends to period 3 attracting cycle :

• 0.17434140717278*%i-0.23080799291989
• 0.57522120945524*%i-0.087122596659277
• 0.55547045915754*%i-0.4332890929585

Absolute value of multiplier of above cycle is 0.94840556944351

Ja, właściciel praw autorskich do tego dzieła, udostępniam je na poniższych licencjach

Udziela się zgody na kopiowanie, rozpowszechnianie oraz modyfikowanie tego dokumentu zgodnie z warunkami GNU Licencji Wolnej Dokumentacji, w wersji 1.2 lub nowszej opublikowanej przez Free Software Foundation; bez niezmiennych sekcji, bez treści umieszczonych na frontowej lub tylnej stronie okładki. Kopia licencji załączona jest w sekcji zatytułowanej GNU Licencja Wolnej Dokumentacji.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International, 3.0 Unported, 2.5 Generic, 2.0 Generic and 1.0 Generic license.

Wolno:

• dzielić się – kopiować, rozpowszechniać, odtwarzać i wykonywać utwór
• modyfikować – tworzyć utwory zależne

Na następujących warunkach:

• uznanie autorstwa – musisz określić autorstwo utworu, podać link do licencji, a także wskazać czy utwór został zmieniony. Możesz to zrobić w każdy rozsądny sposób, o ile nie będzie to sugerować, że licencjodawca popiera Ciebie lub Twoje użycie utworu.
• na tych samych warunkach – Jeśli zmienia się lub przekształca niniejszy utwór, lub tworzy inny na jego podstawie, można rozpowszechniać powstały w ten sposób nowy utwór tylko na podstawie tej samej lub podobnej licencji.

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue

Możesz wybrać, którą licencję chcesz zastosować.

/*  
this is batch file for Maxima  5.13.0
http://maxima.sourceforge.net/
tested in wxMaxima 0.7.1
using draw package ( interface to gnuplot )
to draw on the screen
draws Julia set for f(z)=z*z+c
using modified IIM
modification: stop reversed iteration 
if pixel was hit in reversed orbit  > HitLimit times
Adam Majewski
*/
c:-0.11+0.65569999*%i;   /*    */
HitLimit:14; /* proportional to number of details and time of drawing */
/* resolution is proportional to number of details and time of drawing */
iXmax:500;
iYmax:500;
/* define image size : width:iXmax-0+1;      heght:iYmax-0+1 ;    */
start:elapsed_run_time ();
NumberOfPoints:0;
f(z,c):=z*z+c;
finverseplus(z,c):=sqrt(z-c);
finverseminus(z,c):=-sqrt(z-c);
/* define z-plane ( dynamical ) */
zxMin:-2.0;
zxMax:2.0;
zyMin:-2.0;
zyMax:2.0;
/* */
PixelWidth:(zxMax-zxMin)/iXmax;
PixelHeight:(zyMax-zyMin)/iYmax;
array(Hits,iXmax,iYmax); /* 2D array of hits pixels . Hit > 0 means that point was in orbit */
/* no hits for beginning */
for iX:0 thru iXmax  step 1 do
for iY:0 thru iYmax  step 1 do 
 Hits[iX,iY]:0;
/* compute fixed points of f(z,c) :   z=f(z,c)   */
fixed:float(rectform(solve([z*z+c=z],[z])));
/* Find which is repelling  */
if (abs(2*rhs(fixed[1]))<1) 
then block(
           beta:rhs(fixed[1]),
           alfa:rhs(fixed[2])
          ) 
else block(
           alfa:rhs(fixed[1]),
           beta:rhs(fixed[2])
          );
/* choose repeller as a starting point */
/*save beta in stack */
stack:[beta];
/* make 2 list of points and copy beta to  to lists */ 
xx:makelist (realpart(beta), i, 1, 1); /* list of re(z) */
yy:makelist (imagpart(beta), i, 1, 1); /* list of im(z) */
NumberOfPoints:1;
/* reversed iteration of beta */
block
(loop,
 z:last(stack),
 stack:delete(z,stack), 
 /* inverse iteration - first preimage (root) */
 z:finverseplus(z,c),
 /* translate from world to screen coordinate */
 iX:fix((realpart(z)-zxMin)/PixelWidth),
 iY:fix((imagpart(z)-zyMin)/PixelHeight),
 hit:Hits[iX,iY],
 if hit<HitLimit   
   then block(
    Hits[iX,iY]:hit+1,
    stack:endcons(z,stack), /* push = add z at the end of list stack */
    if hit=0 then block( xx:cons(realpart(z),xx), yy:cons(imagpart(z),yy)),
    NumberOfPoints:NumberOfPoints+1
    ),
    /* inverse iteration - second preimage (root) */
   z:-z,
   /* translate from world to screen coordinate, coversion to integer */
   iX:fix((realpart(z)-zxMin)/PixelWidth),
   iY:fix((imagpart(z)-zyMin)/PixelHeight),
   hit:Hits[iX,iY],
   if hit<HitLimit   
     then block(
       Hits[iX,iY]:hit+1,
       /* push = add z at the end of list stack to continue iteration */
      stack:endcons(z,stack),
      if hit=0 then block( xx:cons(realpart(z),xx), yy:cons(imagpart(z),yy)), /* draw point */
      NumberOfPoints:NumberOfPoints+1	),
      if is(not emptyp(stack)) then go(loop) 
);
stop:elapsed_run_time ();
t:fix(stop-start);
/* draw reversed orbit of beta  using draw package */
load(draw);
draw2d(
 file_name = "miim",
 terminal  = 'png,
 pic_width  = iXmax,
 pic_height = iYmax,
 yrange = [zyMin,zyMax],
 xrange = [zxMin,zyMax],
 title= "Julia set in dynamical plane for f(z,c):=z*z+c drawn using MIIM",
 key = concat("c=",string(c),". There are ",string(NumberOfPoints)," points" ),
 label ([concat("HitLimit=",string(HitLimit)," Time=",string(t)),-1.2,-1.8]),
 xlabel     = "Z.re ",
 ylabel     = "Z.im",
 point_type    = dot,
 point_size    = 8,
 color         = black,
 points(xx,yy)
);